**RAStaff**

**Sample Only**

This document was submitted by students in a previous class. Their requirements were different from yours. We offer it only as a sample of what a project was for that class. Copying this document, in whole or in part, and submitting the result as your own work, would be a violation of the honor code.

<deleted>

## I. Model Design and Overview

The RAStaff.xls spreadsheet model comprises 10 worksheets:

* **Info:** Model version, authors, color coding
* **Input:** All input parameters and data streams that the user can modify for scenario testing are located on the Input worksheet and color coded yellow. The only cells that the user can’t modify are cells that indicate whether the values in a range correctly add up to 100%, cells that calculate the implicit length of service of an RA, and cells that calculate the implicit total number of RAs on staff when the model starts. These cells are designed to help the user in deciding what kind of data to input. The cells that the user can’t modify have been left black and white.
* **AnnualSummary, QtrSummary:** These two worksheets summarize the Output calculations on an annual an quarterly basis. The user should not modify these cells.
* **Output:** This worksheet contains intermediate and final calculations of University product output, number of RA staff needed, and associated salary and overhead costs. The user should not modify these cells. All values on the Output worksheet are calculated from the input data, except for the following numeric constants:
* Productivity Factor = 1;
* Quarter = 4;
* The arrays RANewHiresSchedule / TotalNewRAsHiredByQuarter use “0”s
* **ChartsInput, ChartsOutputStaff,ChartsOutputProducts**: The three worksheets with charts show key input variables (turnover and learning curve), output calculations for staffing/costs; and output calculations for product output / capacity. The charts are automatically generated from the Input, AnnualSummary and QtrSummary worksheets.
* **Names:** This worksheet gives the list of named ranges with abbreviations, location, units of measure, and definition. All names in the RAStaff model are global names. The model uses named ranges instead of absolute cell references in all worksheet formulas, except for in the SUM and AVERAGE calculations on the Output, AnnualSummary, and QtrSummary worksheets.
* **Formulas:** This worksheet displays the formulas used on the Output worksheet. The model mainly uses array arithmetic and matrix multiplication (MMULT function with TRANSPOSE). The other Excel functions that the model uses are SUM; AVERAGE; ROUND; ROUNDUP; and IF. The model contains no macros or non-standard functions.
* On the Output worksheet, SUM is used to calculate the quarterly cost subtotals for salaries, recruiting, benefits, and office space. On the AnnualSummary worksheet, SUM is used to calculate annual product and cost totals from the quarterly data.
* The AVERAGE function is used on the Output worksheet to calculate intermediate annual outputs from the quarterly learning curve, required output, and actual output of RAs on staff. These averages are then used to calculate the number of new RAs needed.
* The ROUND function is used to the convert the number of RAs who stay from one year to the next to whole people. (Array “RAsHiredLastYrRemainingYr2” etc.)
* The ROUNDUP function is used when calculating the number of full-time new staff positions that need to be hired. (Array “RANewHiresYr1” etc.)
* The IF function is used on the Input worksheet in cells that give the user an error message if the inputs in a range don’t add up to 100%. On the Output worksheet, the IF function is used with text labels to expand some arrays (to give all RAs with MBAs the same salary, for example) and to avoid “Error” results in percentage calculations (Array “CapacityMetQtrYr1” etc.). The IF Function is also used in the “RAOutput” range calculations.

The calculations in the Output worksheet basically flow down, then across. In other words, the RA need and costs for Year 1 are calculated; then the results for Year 2 are calculated from Year 1, etc.

The data types are coded as follows

|  |  |  |
| --- | --- | --- |
| Color | Data Type | Location |
| Yellow | User-Modifiable Input Data | Input |
| Light Yellow | Input Data that differs between Scenario 1 and 2 (user-modifiable, TurnoverAnalysis and ProductivityAnalysis)a | Input |
| Orange | Averages | Output |
| Green | Key Output (Category Totals) | Output |
| Blue | Text Commentary | Input /Ouput |

# II. How the Model Works

We will show you a general idea of how we come up with our final calculations:

Input parameter and tables entered by the user.

(1) Computes the ideal amount of publications RAs are required to produce assuming that they perform at 100% productivity.

(2) Computes the number of publications previously hired RAs can produce, factoring in respective productivity.

(3) Computes the number of new RAs to hire annually by subtracting the (2) from (1) and factoring in the new RAs’ productivity level and turnover of existing RAs on staff.

(4) Computes the total number of RAs hired by adding the number of existing RAs and the newly hired RAs.

(5) Computes the associated RA costs to faculty (salary) and University (benefits, training cost, recruitment costs and office allocation costs).

**III. Input Variables** The user-modifiable input variables are described in the Final Report and User Guide.

**IV. Intermediate Output Calculations (on the Output Worksheet)**

* Numbers are taken from the Input Worksheet and processed into output data in the Output Worksheet using IF statements, MMULT and ROUND functions.

1. AnnualSalaryAnalysis

* This table is an extension from the SalaryExp array from the Input worksheet. Using an IF condition that references text labels, we applied the salary cost for each of the 3 RA degrees to the relevant RAs in the 12 RA product-degree types. [=IF(LEFT(ProductDegree,3)=BALabel,BASalary,IF(LEFT(ProductDegree,3)=MBALabel,MBASalary,IF(LEFT(ProductDegree,3)=PhDLabel,PhDSalary,NA())))]

2. TrainingCostAnalysis

* Similar to the AnnualSalaryAnalysis, using an IF condition, we applied the TrainingCost array for each product type to the relevant RAs in the 12 RA product-degree types.

3. IdealRAOutputByTask

* Similar to the TrainingCostAnalysis, taking the data from IdealRAOutput in the Input Worksheet and using the IF statement, we separated ideal RA annual output by product type and applied them to the relevant RAs in the 12 RA product-degree types.

4. AverageProductivity

* In order to smooth out our hiring process and eliminate the need to lay off the excess RAs as they become more productive, we decided to use a quarterly productivity average instead.
* To calculate AverageProductivity, we used the MMULT function for the productivity of a specific year and a productivity factor (an 4x1 array of 1’s) and divide it by 4 (quarter).

[=MMULT(ProductivityYr1,ProductivityFactor)/Quarter]

A similar method is used for Years 2 and 3.

5. RAHired1YrAgoStayYr2

* This array calculates the number of RAs who were hired 1 year before the model started (RAOnStaff1YrAgo) that remained until Year 2 of the model (their third year), using the turnover numbers from the Input sheet.
* We also used the ROUND function to eliminate fractional RAs who are staying.

6. RAOnstaffHiredYr1StayYr2

* This array represents the number of RAs who were hired in Year 1 of the model and decided to stay for Year 2.
* The concept behind the calculations is similar to RAHired1YrAgoStayYr2. However, we will have to determine the number of new RAs hired in Year 1 (RANewHires), which we will explain later, before we can do the computations.

[=ROUND(RAHiredYr1Qtr4\*(1-(RALeavingYr1)),0)]

The method of calculation also holds for RAOnStaffHiredYr1StayYr3 RAs hired in Year 1 of the model who stay for Year 2) and RAOnStaffHiredYr2StayYr3 (RAs hired in Year 2 of the model who stay for Year 3).

**V. Computed Output Calculations (on the Output Worksheet)**

* Computed Output is divided into 3 sections – the number of RAs employed (taking into account productivity), costs and capacity analysis.

# RAs Employed

1. TotalQtrFacOutput

* Total Quarter Faculty Output calculates the faculty’s output publications for each quarter. The total amount of publications will be the same for each year.
* To figure this output, we took the FacTenure, MMULT it with FacOutput, and MMULT it again with QtrOutput. The quarterly output (QtrOutput) gives the production difference between each quarter (seasonality).

[=MMULT(TRANSPOSE(MMULT(TRANSPOSE(FacTenure),FacOutput)),QtrOutput)]

2. RANeedQtrArticle

* This array tells us how many RAs are needed to produce the University’s articles after subtracting an amount that is produced by central research services, assuming that the RAs perform at 100% productivity. In other words, if there were no learning curve or turnover issues, this would be the entire model.

[=(TotalQtrFacOutput\*TRANSPOSE(1-CtrCapacity))/(TRANSPOSE

(IdealRAOutput)/Quarter)]

* The calculations are the same for RANeedQtrBook, RANeedQtrRes and RANeedQtrAnalysts.

3. RANeedByEd

* Knowing the number of RAs needed to produce the remaining articles, we multiply that by DegreeAllocation, which is the desired degree type mix for RAs working on each type of publication (based on budget or skill level). This will give us for the number of BA, MBA, PhD RAs needed for each product type.
* [=ArticleEdRatio\*RANeedQtrArticle] The calculation is the same for each product type.

4. RequiredRAOutput

* After identifying the number of degree holders for each product, we can now calculate the amount of output that the total RA pool required to produce. The total of this number must be the same as total faculty output less the publications produced by the central services.
* All we did in this array is to multiply the RANeedByEd with quarterly ideal RA output.

[=RANeedQtrByEd\*(IdealRAOutputByTask/Quarter)]

5. AvgRequiredRAOutput

* As the RequiredRAOutput differs for each quarter, we decide to take the average of the year. This will help smooth our employment of new RAs over time.

6. RAOnStaff2YrAgoOutputYr1

* This array calculates the Year 1output of the RAs hired 2 years ago before the model started. It takes the starting number of RAs 2 years ago (RAOnStaff2YrAgo), and multiply it with MMULT of IdealRAOutputByTask and QtrOutput, before multiplying it again with ProductivityYr3 (because they were entering their 3rd year).

[RAOnStaff2YrAgo\*(MMULT(IdealRAOutputByTask,QtrOutput))

\*ProductivityYr3]

* This is the same for RAOnStaff1YrAgoOutputYr1, RAOnStaff1YrAgoOutputYr2, RAOnStaffHiredYr1OutputYr2, RAOnStaffHiredYr1OutputYr3 and RAOnStaffHiredYr2OutputYr2.
* The main difference between them is the number of RAs staying for their 2nd or 3rd year and their respective productivity level.

7. Avg2YrAgoRAOnstaffOutputYr1

* This is the average for the above RAOnStaff2YrAgoOutputYr1 results. Using an average, we can standardize the RAs output for each quarter.
* This is the same for Avg1YrAgoRAOnStaffOutputYr1, Avg1YrAgoRAOnStaffOutputYr2, AvgRAHiredYr1OutputYr2, AvgRAHiredYr1OutputYr3 and AvgRAHiredYr2OutputYr3.

8. RAOutput

* This array calculates the amount of publications needed to be written by the newly hired RAs for each year.
* An IF function is used in the computation because we do not want negative output. If the RAs employed can produce more than the required, it will result in a 0 instead of a negative number.

[=IF(AvgReqRAOutput-Avg2YrAgoRAOnStaffOutputYr1-Avg1YrAgoRAOnStaffOutputYr1>0,AvgReqRAOutput-Avg2YrAgoRAOnStaffOutputYr1-Avg1YrAgoRAOnStaffOutputYr1,0)]

9. RANewHires

* After determining the amount of publications needed to be produced by the newly hired RAs, we can easily figure out the number of new RAs required by dividing it by the multiplication of productivity and the RA’s quarterly output.

[=ROUNDUP((RAOutputYr1)/(AvgProductivityYr1\*IdealRAOutputByTask/Quarter),0)\*PercentHire]

* ROUNDUP is used in this case because we cannot hire a fraction of an RA to produce a certain level of output.
* PercentHire on the Input sheet is an added feature that allows the user to play around with the number of new hires for scenario testing.

10. RANewHiresSchd

* This simply tells us that new RAs are only hired once a year (in the 1st quarter of each year) and there are no other additional hires in the 3 other quarters.

11. TotalRAStaff

* This is a simple addition of newly hired RAs and the RAs who stayed for their 2nd and 3rd year. The calculation is the same for Years 2 and 3.

[=RANewHiresYr1+RAOnStaff2YrAgo+RAOnStaff1YrAgo]

# Costs

1. TotalRASalary

* Total RA salary is made up of the salary for new and remaining RAs, so the user can more easily see the cost of the two different staff goups. New RA salary is the total salary of the newly hired RAs and Remaining RA salary is the salary of the RAs who stayed for their 2nd and 3rd year.

[=TotalRANewHires\*(AnnualSalaryAnalysis/Quarter)]

[=(TotalRAStaff-TotalRANewHires)\*(AnnualSalaryAnalysis/Quarter)]

[=NewRASalary+RemainingRASalary]

2. Benefits

* Total benefits are calculated by taking a percentage of Total RA Salary. The percentage can be found on the Input Worksheet.

[=TotalRAStaffSalary\*Benefits]

3. Training Cost

* Training Cost is calculated by multiplying the TrainingCostAnalysis with the NewHiresSchd. Training costs occur only once a year and in the 1st quarter. It only applies to the newly hired RAs. They are specific to product type.

[=RANewHiresSchd\*TrainingCostAnalysis]

4. Recruitment Cost

* Recruitment cost is calculated in 2 steps. First, we have to determine the number of new hires who were recruited by either the faculty or HR department.

[RecruitmentPercent\*TotalNewRAsHiredPerQtr]

Second, once we determined the number of new hires by each recruitment type then we can multiply it with the cost associated.

[RecruitmentAnalysis\*RecruitmentCostPerRA]

5. Office Space Cost

* Similar to recruitment cost, we first have to determine the number of RAs who were assigned with an office space.

[=TotalRAStaffPerQtr\*OfficeSpaceAllocation]

Next, we will multiply that number by the cost of office space.

[=OfficeSpaceAnalysis\*OfficeSpaceCost]

6. OverheadCostPerQuarter

* Overhead Cost totals all cost items except for salary. Overhead is paid for by the University; RA salary costs come out of faculty budgets.

[=TotalBenefitsPerQtr+TotalTrainingCostPerQtr+TotalRecruitmentCostPerQtr+TotalOfficeSpaceCostPerQtr]

# Capacity Analysis

* The need for capacity analysis is to allow the user to see if the RAs are over or under producing the output required. Under producing will only occur when the user scales down the number of newly hired RAs using the PercentHire input. (On the AnnualSummary vs QtrSummar worksheets, the user can also see that underproducing occurs on a quarterly basis within each of the 12 RA types, because the hiring is not geared towards meeting each quarter’s exact needs only annual averages. Undercapacity doesn’t occur overall when measured by product output on an annual basis).

1. ActualRAOutput

* A simple computation is used to figure out the actual RA output for each year. The main idea is to add up the number of RAs either those who stayed behind or are newly hired with their productivity factored in and multiply that by the IdealRAOutputByTask per quarter.

[=(RAOnStaff2YrAgo\*ProductivityYr3+RAOnStaff1YrAgo\*ProductivityYr2+RANewHiresYr1\*PercentHire\*ProductivityYr1)\*(IdealRAOutputByTask/Quarter)]

The same concept goes for Years 2 and 3.

2. Capacity Difference

* The result is obtained by subtracting the actual output of the RAs by the required amount.

[=ActualOutputYr1-RequiredRAOutput]

3. Capacity Met

* These blocks of arrays show the percentage of capacity difference for each quarter in each year. An IF condition is used to eliminate invalid numbers when 0 is divided by some integer.

[=IF(CapacityDiffYr1=0,0,CapacityDiffYr1/RequiredRAOutput)]